//
// Diesen Wuerfel habe ich mal auf der Drehbank gemacht.
// Dummerweise IST KEIN 3D programm in der Lage DIESEN
// wuerfel dreidimensional abzubilden. Bis auf POVRAY
//
// (C) by Wolfgang Hurst
//

#include "colors.inc"
#include "textures.inc"
#include "skies.inc"

// Wir Definieren die Aussparung
#declare s1 = cylinder { <-15,0,0>, <-2,0,0>, 35 }
#declare s2 = cylinder { <-14,0,0>, <7,0,0>, 24  }
#declare s3 = cylinder { <-13,0,0>, <14,0,0>, 15  }
#declare s = union { object { s1 } object { s2 } object { s3 } }

camera {
	location <70, 70, -280>
	look_at <0, 80, 0>
}

light_source {
	<150, 250, -250>
	color White
}

light_source {
	<-150, 250, -150>
	color White
}

light_source {
	<0, 150, -100>
	color White
}

#declare Sky =
sky_sphere { S_Cloud3 }

#declare Plane=
plane { 
	<0,1,0>, -0
	texture {
		pigment {
			crackle
			color_map {
				[ 0.0 color rgb<0.356, 0.321, 0.274> ]
				[ 0.1 color rgb<0.611, 0.500, 0.500> ]
				[ 0.4 color rgb<0.745, 0.623, 0.623> ]
				[ 1.0 color rgb<0.837, 0.782, 0.745> ]
			}
			warp { turbulence 0.6 }
			sine_wave
			scale 20
		}
		finish {
			ambient 0.4
			diffuse 0.3
			specular 0.1
			reflection {
				0.2, 0.6
				fresnel on
			}
		conserve_energy
		}
	}
}

//fog { distance 100 color rgbf <0,0,0,0.2> fog_type 2 fog_offset 40 fog_alt 1 }

// der wuerfel
#declare InboundCube = 
union {
	object {
		difference {
			box { <-39, -39, -39> <39, 39, 39> }
			object { s rotate <0, 0, 0> translate <-25, 0 , 0> }
			object { s rotate <0, 0, 180> translate <25, 0 , 0> }
			object { s rotate <0, 0, 90> translate <0, -25 , 0> }
			object { s rotate <0, 0, -90> translate <0, 25 , 0> }
			object { s rotate <0, 90, 0> translate <0, 0 , 25> }
			object { s rotate <0, -90, 0> translate <0, 0 , -25> }
		}
		rotate <0, 45, 0>
		rotate <0, 0, 55.05>
		translate <0, 69.28, 0> // drehung
		translate <0, 60, 0> // stiellaenge
	}
	cylinder { <0,0,0>, <0,5,0>, 60 } // Sockel
	cone { <0,5,0> 60, <0,8,0>, 57 } // fase
	cylinder { <0,0,0>, <0,67,0>, 4 } // stiel

	texture { Gold_Metal }
	finish {
		ambient 0.4
		diffuse 0.8
		reflection 0.2
		specular 0.2
		phong 0.8
	}
}

// Der Outbound Wuerfel
#declare OutCutter =
difference {
	box { <-13, -40, -40>, <13, 40, 40> }
	cylinder { <-15, 0, 0>, <15, 0, 0>, 39 }
}

#declare OutboundCube =
union {
	object {
		difference {
			box { <-39, -39, -39> <39, 39, 39> }
			object { OutCutter rotate <0, 0, 0> translate <-27, 0 , 0> }
			object { OutCutter rotate <0, 0, 0> translate <27, 0 , 0> }
			object { OutCutter rotate <0, 0, 90> translate <0, 27 , 0> }
			object { OutCutter rotate <0, 0, 90> translate <0, -27 , 0> }
			object { OutCutter rotate <0, 90, 0> translate <0, 0 , 27> }
			object { OutCutter rotate <0, 90, 0> translate <0, 0 , -27> }
		}
		rotate <0, 45, 0>
		rotate <0, 0, 55.05>
		translate <0, 49.28, 0> // drehung
		translate <0, 60, 0> // stiellaenge
	
	}
	
	union {
		cylinder { <0,0,0>, <0,5,0>, 45 } // Sockel
		cone { <0,5,0> 45, <0,8,0>, 42 } // fase
		cylinder { <0,0,0>, <0,67,0>, 3 } // stiel
	}

	texture { Chrome_Metal }
	finish {
		ambient 0.2
		diffuse 0.7
		reflection 0.2
		phong 0.8
	}
}

// Ein Cylindrischen Spiegel nach hinten stellen, zum gucken
#declare MirrorBall1 =
object {
	sphere { <0, 0, 250>, 150 }
	texture { 
		//Mirror 
		pigment {
			color White
		}
		finish {
			ambient 0.1
			diffuse 0.2
			reflection 0.6
			phong 0.2
		}
	}
}

sky_sphere { Sky }
object { Plane }
object { InboundCube translate <-70, 0, 0> }
object { OutboundCube translate <70, 0, 0> }
object { MirrorBall1 }