#include "colors.inc"
#include "textures.inc"
#include "skies.inc"
#include "functions.inc"

global_settings {
	max_trace_level 255
}

camera {
	location <0, 1, -10>
	look_at <-3, 0, 0>
}

// mini licht damit man vorne auch was sieht
light_source {
	<0, 10, -1000>
	color <0.3, 0.3, 0.3>
}

// himmel
sky_sphere { S_Cloud3 }


// wasser
plane {
	<0,1,0>, 0
	texture {
		Polished_Chrome
	}
	normal {
		bumps 0.3
		scale 0.05
		turbulence 0.6
	}
}

// sonnenlicht
light_source {
	<80, -5, 500>
	color red 1.0 green 0.7
}

// sonnen fake :-)
plane {
	<0, 0, 1>, 500
	no_shadow
	pigment {
		wood scale 4000
		color_map {
		        [0.0 0.047 color rgb <0.8,0.5,0>*4
		                 color rgb <0.8,0.5,0>*2 ]
		        [0.047 0.05 color rgb <0.8,0.5,0>*2
		                 color rgb <0.8,0.5,0>*2 ]
		        [0.05 0.9 color rgb <0.8,0.5,0> 
		                 color rgbft <0,0,0,0,1> ]
		        [0.9 1.0 color rgbft <0,0,0,0,1> 
		                 color rgbft <0,0,0,0,1> ]
		}
		translate <0, -10, 0>
	}
	finish {
		ambient 0.5
	}
	translate <80, -10, 500>
}

// meine berge
#declare MaFonction = function {pattern{wrinkles scale 1}}
height_field {
	function image_width * 2, image_height * 2 { 
		MaFonction(x,y,z)*MaFonction(x,y,z)*MaFonction(x,y,z)
	}
	scale <200, 200, 200>
	translate <-30, -30, 80>
	rotate <0, -59, 0>

	pigment {
		slope y
		color_map { 
			[0 White]
			[0.10 SteelBlue*0.1]
			[0.20 White*2]
			[0.25 Gray95]
			[0.30 Gray80]
			[0.40 MediumForestGreen]
		}
	}
}

// nochmal ganz klein und rechts
height_field {
	function image_width, image_height { 
		MaFonction(x,y,z)*MaFonction(x,y,z)*MaFonction(x,y,z)
	}
	scale 4
	translate <-0.25, -0.5, -8>

	pigment {
		slope y
		color_map { 
			[0 White]
			[0.10 SteelBlue*0.1]
			[0.20 White*2]
			[0.25 Gray95]
			[0.27 Gray80]
			[0.30 MediumForestGreen]
		}
	}
}

// mein Nebel Fetzen
plane {
	<0,1,0>, 0
	pigment {
		bozo
		turbulence 0.65
		octaves 6
		omega 0.7
		lambda 2
		color_map {
			[ 0.0 0.3 color rgbft <1,1,1,1,0>
			          color rgbft <1,1,1,1,0> ]
			[ 0.3 0.55 color rgbft <1,1,1,1,0>
			          color rgbft <0,0,0,0,1> ]
			[ 0.55 1.0 color rgbft <0,0,0,0,1>
			          color rgbft <0,0,0,0,1> ]
		}
	}
	finish {
		ambient 2.0
	}
	scale 10
	translate <5, 0.5, -3>
}