#include "colors.inc"
#include "textures.inc"
#include "skies.inc"
#include "functions.inc"

camera {
	location <0, 1, -10>
	look_at <-3, 0, 0>
}

// ambient light 
light_source {
	<0, 10, -1000>
	color <0.3, 0.3, 0.3>
}

sky_sphere { S_Cloud3 }

// mein wasser
plane {
	<0,1,0>, 0
	texture {
		Polished_Chrome
	}
	normal {
		bumps 0.3
		scale 0.05
		turbulence 0.6
	}
}

// meine sonne
light_source {
	<80, -5, 500>
	color red 1.0 green 0.7
	looks_like {
		sphere {
			<80, -5, 500>, 70
			pigment {
				color red 1.0 green 0.7 filter 0.35
			}
			finish {
				ambient 1.0
				diffuse 0.0
			}
		}
	}
}

// meine berge
#declare MaFonction = function {pattern{wrinkles scale 1}}
height_field {
	function image_width * 2, image_height * 2 { 
		MaFonction(x,y,z)*MaFonction(x,y,z)*MaFonction(x,y,z)
	}
	scale <200, 200, 200>
	translate <-30, -30, 80>
	rotate <0, -59, 0>

	pigment {
		slope y
		color_map { 
			[0 White]
			[0.10 SteelBlue*0.1]
			[0.20 White*2]
			[0.25 Gray95]
			[0.30 Gray80]
			[0.40 MediumForestGreen]
		}
	}
}

// nochmal ganz klein und rechts
height_field {
	function image_width, image_height { 
		MaFonction(x,y,z)*MaFonction(x,y,z)*MaFonction(x,y,z)
	}
	scale 4
	translate <-0.25, -0.5, -8>

	pigment {
		slope y
		color_map { 
			[0 White]
			[0.10 SteelBlue*0.1]
			[0.20 White*2]
			[0.25 Gray95]
			[0.27 Gray80]
			[0.30 MediumForestGreen]
		}
	}
}